Most Valuable Professional


View Jan Karel Pieterse's profile on LinkedIn subscribe to rss feed
Subscribe in a reader

Subscribe to our mailing list

* indicates required

Audit !!!

Check out our RefTreeAnalyser
the ultimate Excel formula auditing tool.

Trainings

Excel VBA Masterclass (English)
Excel VBA for Financials (Dutch)

Third party tools

Speed up your file

FastExcel
The best tool to optimise your Excel model!

Repair your file

Stellar Phoenix Excel Repair
Best tool to repair corrupt Excel sheets and objects
Home > English site > Articles > Pivottable Slicers > Show Selected Items

Showing selected Slicer items on a worksheet

Even though it is often sufficient to see the slicer on the workbook it can be useful to be able to get a list of the filtered sliceritems in a worksheet cell. If your pivottable is built using a powerpivot model, then you can access this information by using the CUBERANKEDMEMBER worksheet function. If however the slicer was built off of a "normal" pivottable, then you need a bit of VBA code in a User Defined Function (UDF).

The slicer name

In order to retrieve the selected slicer items we need slicer's internal name, both for the CUBERANKEDMEMBER function and for the UDF. This name can be shown in the userinterface by right-clicking the slicer in question and selecting "Slicer settings". The name you are looking for is marked in red in the screenshot below and indicated by "Name to use in formulas":

Slicer settings dialog, needed name highlighted in red

CUBERANKEDMEMBER (for powerpivot slicers)

The CUBERANKEDMEMBER function returns an array of selected items and hence needs to be into as many (vertical) cells as you expect will be selected in the slicer. See the screenshot below (note the formula has ; as the delimiter, many users need to use the comma instead).

Using the CUBERANKEDMEMBER function

Note, that when less items are selected than the number of cells the function was entered into, the excess cells will show #N/A.

These #N/A's can be hidden with:

=IFERROR(CUBERANKEDMEMBER("PowerPivot Data",Slicer_Name,ROW()-ROW($G$5)),"")

or counted with

=IF(ROW()-ROW($G$5)<=CUBESETCOUNT(CUBESET("PowerPivot Data",Slicer_Name)),CUBERANKEDMEMBER("PowerPivot Data",Slicer_Name,ROW()-ROW($G$5)),"")

The UDF

The code sample below must be placed in a normal module:

Public Function GetSelectedSlicerItems(SlicerName As String) As String
    Dim oSc As SlicerCache
    Dim oSi As SlicerItem
    Dim lCt As Long
    On Error Resume Next
    Application.Volatile
    Set oSc = ThisWorkbook.SlicerCaches(SlicerName)
    If Not oSc Is Nothing Then
        For Each oSi In oSc.SlicerItems
            If oSi.Selected Then
                GetSelectedSlicerItems = GetSelectedSlicerItems & oSi.Name & ", "
                lCt = lCt + 1
            End If
        Next
        If Len(GetSelectedSlicerItems) > 0 Then
            If lCt = oSc.SlicerItems.Count Then
                GetSelectedSlicerItems = "All Items"
            Else
                GetSelectedSlicerItems = Left(GetSelectedSlicerItems, Len(GetSelectedSlicerItems) - 2)
            End If
        Else
            GetSelectedSlicerItems = "No items selected"
        End If
    Else
        GetSelectedSlicerItems = "No slicer with name '" & SlicerName & "' was found"
    End If
End Function

The function takes the slicername as its argument and returns a text string (comma delimited) containing the selected items. In a worksheet cell the formula would look like this:

=GetSelectedSlicerItems("Slicer_TeamID2")

Conclusion

Well, I hope I got you started with getting your head around how slicers work and how to address them using VBA. I find Slicers a real gem in Excel 2010 and 2013. A great addition to the product!

 


 


Comments

Showing last 8 comments of 100 in total (Show All Comments):

 


Comment by: Jan Karel Pieterse (6/30/2017 3:29:36 PM)

Hi Biprajit,

If you right-click the slicer and select Slicer settings the dialog shows two names. The name you need is the "Name to use in formulas"

 


Comment by: Biprajit goswami (7/6/2017 11:30:19 AM)

The name to be used in formulae is the name suggested by the intellisense. Even using that in the function gives me the same result " no slicer with name was found"

 


Comment by: Jan Karel Pieterse (7/6/2017 2:03:58 PM)

Hi Biprajit,

You did put the slicername in quotes, like I show above?

 


Comment by: Biprajit (7/6/2017 7:03:25 PM)

Thank you sir..after i put the name within quotes, i got the correct slicer selection.

 


Comment by: Geoff Lilley (7/7/2017 11:53:01 AM)

The modifications I made are as follows:


Public Function GetSelectedSlicerItems(SlicerName As String, multiItems As Long, Optional tooMany As String) As Variant
    If tooMany = "" Then tooMany = "Multiple Items"
    Dim oSc As SlicerCache
    Dim oSi As SlicerItem
    Dim oSItems As SlicerItems
    Dim lCt As Long
    On Error Resume Next
    Application.Volatile
    Set oSc = ActiveWorkbook.SlicerCaches(SlicerName)
    If Not oSc Is Nothing Then
        Err.Clear
        Set oSItems = oSc.SlicerCacheLevels(1).SlicerItems
        If Err.Number > 0 Then
            Set oSItems = oSc.SlicerItems
        End If
        For Each oSi In oSItems
            If oSi.Selected And (oSi.HasData Or CountNoDataItems) Then
                GetSelectedSlicerItems = GetSelectedSlicerItems & oSi.Name & ","
                lCt = lCt + 1
            ElseIf oSi.HasData = False And CountNoDataItems Then
                lCt = lCt + 1
            End If
        Next
        If Len(GetSelectedSlicerItems) > 0 Then
            If lCt >= multiItems Then
                GetSelectedSlicerItems = tooMany
            ElseIf lCt = oSItems.Count Then
                GetSelectedSlicerItems = allItems
            Else
                If ReturnArray Then
                    GetSelectedSlicerItems = Application.Transpose(Split(GetSelectedSlicerItems, ","))
                End If
            End If
        Else
            GetSelectedSlicerItems = "No items selected"
        End If
    Else
        GetSelectedSlicerItems = "No slicer with name '" & SlicerName & "' was found"
    End If
    If Right(GetSelectedSlicerItems, 1) = "," Then GetSelectedSlicerItems = Left(GetSelectedSlicerItems, Len(GetSelectedSlicerItems) - 1)
    GetSelectedSlicerItems = Replace(GetSelectedSlicerItems, ",", ", ")
End Function

 


Comment by: Jan Karel Pieterse (7/7/2017 11:54:07 AM)

Hi Geoff,

Thanks! I managed to publish your comment by removing some lines of text. TBH I don't know what triggered the spam filter :-)

 


Comment by: Gale (7/18/2017 5:30:35 PM)

A noob here, whatever I do I only get the first value in each and every cell, could you show how the array formula looks for this and what cells does it refer to?

 


Comment by: Jan Karel Pieterse (7/18/2017 9:45:06 PM)

Hi Gale,

You must select a bunch of cells and then control shift enter the formula.

 


Have a question, comment or suggestion? Then please use this form.

If your question is not directly related to this web page, but rather a more general "How do I do this" Excel question, then I advise you to ask your question here: www.eileenslounge.com.

Please enter your name (required):

Your e-mail address (optional but if you want me to respond it helps!; will not be shown, nor be used to send you unsolicited information):

Your request or comment:

To post VBA code in your comment, use [VB] tags, like this: [VB]Code goes here[/VB].